C++ 20 module target

[HodarinS]

add compile target c++ 20modules. nolhman_json tomlplusplus have same targets for import modules

little suggestion

option(ARGPARSE_BUILD_MODULES "Build C++ modules support" OFF)
option(ARGPARSE_MODULE_USE_STD_MODULE "Build with modules C++ import std" OFF)
if(ARGPARSE_BUILD_MODULES)
  add_library(argparse_modules)
  add_library(argparse::modules ALIAS argparse_modules)
  target_sources(
    argparse_modules PUBLIC FILE_SET CXX_MODULES FILES
                            ${CMAKE_CURRENT_LIST_DIR}/module/argparse.cppm)
  target_link_libraries(argparse_modules PRIVATE argparse::argparse)
  if(ARGPARSE_MODULE_USE_STD_MODULE)
    target_compile_definitions(argparse_modules PRIVATE -DARGPARSE_MODULE_USE_STD_MODULE=1)
    target_compile_features(argparse_modules PUBLIC cxx_std_23)
  else()
    target_compile_features(argparse_modules PUBLIC cxx_std_20)
  endif()
endif()

[wanjiadenghuo111]

亲，来信已经收到！祝你快乐！

[HodarinS]

open pull request

[Blind-Guess-Senior]

I'm not a native English speaker. Apologize for protential grammar mistakes.

As a temporary solution, this config works well (at least on my machine):

FetchContent_Declare(
  argparse
  GIT_REPOSITORY https://github.com/p-ranav/argparse.git
  GIT_TAG v3.2
)
FetchContent_MakeAvailable(argparse)

add_library(profile_argparse_module STATIC)

target_sources(profile_argparse_module
  PUBLIC
    FILE_SET CXX_MODULES
      BASE_DIRS
        "${argparse_SOURCE_DIR}/module"
      FILES
        "${argparse_SOURCE_DIR}/module/argparse.cppm"
)
target_link_libraries(profile_argparse_module
  PRIVATE
    argparse::argparse
)

# replace c++ edition with yours.
target_compile_features(profile_argparse_module PUBLIC cxx_std_23)

# let argparse.cppm itself using import std by passing macro.
# if you don't use import std; just ignore things below.
target_compile_definitions(profile_argparse_module
  PRIVATE
    ARGPARSE_MODULE_USE_STD_MODULE
)
set_target_properties(profile_argparse_module PROPERTIES
  CXX_MODULE_STD ON
  CXX_EXTENSIONS OFF
)

Then target profile_argparse_module to your executable

add_executable(your-target "your-file")
target_link_libraries(your-target
  PRIVATE
    profile_argparse_module
)

Hope oneday we can use modular argparse directly. Although it seems difficult since this project haven't been updated for a year.