C#: Add downgrade script.

Author: michaelnebel

csharp/downgrades/19b8cc3e2dc768d4cbc03d6e3773b709bbebd036/assignments.ql

@@ -0,0 +1,48 @@
+class Expr extends @expr {
+  string toString() { none() }
+}
+
+class ControlFlowElement extends @control_flow_element {
+  string toString() { none() }
+}
+
+predicate assignmentKind(int kind) {
+  // | 63 = @simple_assign_expr
+  // | 80 = @add_event_expr
+  // | 81 = @remove_event_expr
+  // | 83 = @local_var_decl_expr
+  kind = [63, 80, 81, 83]
+}
+
+predicate compoundAssignmentKind(int kind) {
+  // | 64 = @assign_add_expr
+  // | 65 = @assign_sub_expr
+  // | 66 = @assign_mul_expr
+  // | 67 = @assign_div_expr
+  // | 68 = @assign_rem_expr
+  // | 69 = @assign_and_expr
+  // | 70 = @assign_xor_expr
+  // | 71 = @assign_or_expr
+  // | 72 = @assign_lshift_expr
+  // | 73 = @assign_rshift_expr
+  // | 119 = @assign_coalesce_expr
+  kind = [64, 65, 66, 67, 68, 69, 70, 71, 72, 73, 119]
+}
+
+predicate isAssignmentOrCompoundAssignment(Expr ass) {
+  exists(int kind | assignmentKind(kind) or compoundAssignmentKind(kind) |
+    expressions(ass, kind, _)
+  )
+}
+
+query predicate new_expr_parent(Expr e, int child, ControlFlowElement parent) {
+  if isAssignmentOrCompoundAssignment(parent)
+  then
+    // Swap children for assignments, local variable declarations and add/remove event.
+    child = 0 and expr_parent(e, 1, parent)
+    or
+    child = 1 and expr_parent(e, 0, parent)
+  else
+    // Copy the expr_parent relation.
+    expr_parent(e, child, parent)
+}