JavaEditionMods/settings.gradle.kts at main · IMB11-Mods/JavaEditionMods · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
pluginManagement {
    includeBuild("build-logic")
    repositories {
        gradlePluginPortal()
        mavenCentral()
        maven("https://maven.fabricmc.net/")
        maven("https://maven.neoforged.net/releases/")
        maven("https://maven.kikugie.dev/releases/")
        maven("https://maven.kikugie.dev/snapshots/")
    }
}

plugins {
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
    id("dev.kikugie.stonecutter") version "0.9.8"
}

rootProject.name = "JavaEditionMods"

val modTargets = mapOf(
    "fog" to listOf("26.2", "26.3"),
    "mru" to listOf("26.2", "26.3"),
    "sounds" to listOf("26.3"),
    "shields" to listOf("26.2", "26.3"),
    "glass" to listOf("26.2"),
    "snow" to listOf("26.2", "26.3")
)

dependencyResolutionManagement {
    versionCatalogs {
        modTargets.values.flatten().distinct().forEach { minecraft ->
            create("mc${minecraft.replace('.', 'x')}") {
                from(files("gradle/minecraft/$minecraft.versions.toml"))
            }
        }
    }
}

stonecutter {
    create(rootProject) {
        modTargets.forEach { (mod, targets) ->
            branch(mod) {
                targets.forEach { minecraft ->
                    listOf("fabric", "neoforge").forEach { loader ->
                        version("$minecraft-$loader", minecraft.split('.').take(2).joinToString("."))
                            .buildscript("build.$loader.gradle.kts")
                    }
                }
            }
        }
        vcsVersion.set("26.2-fabric")
    }
}